ソース掲示板




すべてから検索

キーワード   条件 表示 現行ログ 過去ログ トピックス 名前 本文
VBScript : Windows 標準 のCDO メール送信 / GMail 用 / cc bcc HTML メール
日時: 2014/02/28 16:19
名前: lightbox



オンラインライブラリを使った、cdo_gmail.wsf / GMail 用
添付ファイルを省略する場合は "" とします

※ Crun は、コマンドプロンプトでの実行を強制します
※ cc bcc HTML メール は、さらに下の記事です 汎用コード( cdo_gmail.vbs ) Yahoo! の場合の設定部分 / サーバー、ユーザ等
<JOB>
<COMMENT>
************************************************************
 WSH 実行スケルトン
************************************************************
</COMMENT>

<SCRIPT language="VBScript" src="http://homepage2.nifty.com/lightbox/laylaClass.vbs"></SCRIPT>
<SCRIPT language="VBScript">
' ***********************************************************
' 処理開始
' ***********************************************************
Call laylaFunctionTarget( "http://homepage2.nifty.com/lightbox/" )
Call laylaLoadFunction( "baseFunction.vbs" )
Call laylaLoadFunction( "toolFunction.vbs" )

Crun

' ***********************************************************
' ファイル添付なし
' ***********************************************************
result = CDOSendMail( _
	"smtp.gmail.com:465:ssl", _
	"あなたです <xxxxxxxx@nifty.com>", _
	"わたしです <xxxxxxxx@gmail.com>" & vbTab & "xxxxxxxx:パスワード", _
	"件名の文字列 : " & Now(), _
	"テキスト本文" & vbCrLf & "改行は vbCrLf" , _
	"" _
)
if result = "" then
	Wscript.Echo "送信が完了しました"
else
	Wscript.Echo result
end if

' ***********************************************************
' ファイル添付あり
' ***********************************************************
result = CDOSendMail( _
	"smtp.gmail.com:465:ssl", _
	"あなたです <xxxxxxxx@nifty.com>", _
	"わたしです <xxxxxxxx@gmail.com>" & vbTab & "xxxxxxxx:パスワード", _
	"件名の文字列 : " & Now(), _
	"テキスト本文" & vbCrLf & "改行は vbCrLf" , _
	"C:\Users\lightbox\Desktop\画像\_img.jpg" _
)
if result = "" then
	Wscript.Echo "送信が完了しました"
else
	Wscript.Echo result
end if

' ***********************************************************
' ファイル添付あり( 複数 )
' ***********************************************************
result = CDOSendMail( _
	"smtp.gmail.com:465:ssl", _
	"あなたです <xxxxxxxx@nifty.com>", _
	"わたしです <xxxxxxxx@gmail.com>" & vbTab & "xxxxxxxx:パスワード", _
	"件名の文字列 : " & Now(), _
	"テキスト本文" & vbCrLf & "改行は vbCrLf" , _
	"C:\Users\lightbox\Desktop\画像\_img.jpg" & vbTab & "C:\Users\lightbox\Downloads\del.gif" _
)
if result = "" then
	Wscript.Echo "送信が完了しました"
else
	Wscript.Echo result
end if

</SCRIPT>
</JOB>
メンテナンス

VBScript : CDO メール送信 / GMail 用 / cc bcc HTML メール ( No.1 )
日時: 2014/02/28 16:13
名前: lightbox


日時: 2014/02/28 16:13
名前: lightbox
CC BCC はどちらか片方で、両方指定すると CC になります。

▼ cdo_gmail2.wsf
<JOB>
<COMMENT>
************************************************************
 WSH 実行スケルトン
************************************************************
</COMMENT>

<SCRIPT language="VBScript" src="http://homepage2.nifty.com/lightbox/laylaClass.vbs"></SCRIPT>
<SCRIPT language="VBScript">
' ***********************************************************
' 処理開始
' ***********************************************************
Call laylaFunctionTarget( "http://homepage2.nifty.com/lightbox/" )
Call laylaLoadFunction( "baseFunction.vbs" )
Call laylaLoadFunction( "toolFunction.vbs" )

Crun

' ***********************************************************
' CC + HTML メール
' ***********************************************************
result = CDOSendMail2( _
	"smtp.gmail.com:465:ssl", _
	"あなたです <xxxxxxxx@nifty.com>", _
	"わたしです <xxxxxxxx@gmail.com>" & vbTab & "xxxxxxxx:パスワード", _
	"件名の文字列 : " & Now(), _
	"テキスト本文" & vbCrLf & "改行は vbCrLf" , _
	"C:\Users\lightbox\Desktop\画像\_img.jpg" , _
	"宛先1,宛先2", _
	"", _
	"<img src=""http://winofsql.jp/image/winofsql.png"">" _
)
if result = "" then
	Wscript.Echo "送信が完了しました"
else
	Wscript.Echo result
end if

' ***********************************************************
' BCC
' ***********************************************************
result = CDOSendMail2( _
	"smtp.gmail.com:465:ssl", _
	"あなたです <xxxxxxxx@nifty.com>", _
	"わたしです <xxxxxxxx@gmail.com>" & vbTab & "xxxxxxxx:パスワード", _
	"件名の文字列 : " & Now(), _
	"テキスト本文" & vbCrLf & "改行は vbCrLf" , _
	"C:\Users\lightbox\Desktop\画像\_img.jpg" , _
	"", _
	"宛先1,宛先2", _
	"" _
)
if result = "" then
	Wscript.Echo "送信が完了しました"
else
	Wscript.Echo result
end if

' ***********************************************************
' HTML メール
' ***********************************************************
result = CDOSendMail2( _
	"smtp.gmail.com:465:ssl", _
	"あなたです <xxxxxxxx@nifty.com>", _
	"わたしです <xxxxxxxx@gmail.com>" & vbTab & "xxxxxxxx:パスワード", _
	"件名の文字列 : " & Now(), _
	"テキスト本文" & vbCrLf & "改行は vbCrLf" , _
	"C:\Users\lightbox\Desktop\画像\_img.jpg" , _
	"", _
	"", _
	"<img src=""http://winofsql.jp/image/winofsql.png"">" _
)
if result = "" then
	Wscript.Echo "送信が完了しました"
else
	Wscript.Echo result
end if

</SCRIPT>
</JOB>
このアーティクルの参照用URLをクリップボードにコピー メンテナンス
VBScript : Windows 標準 のCDO メール送信 / GMail 用 / 汎用コード ( No.2 )
日時: 2014/02/28 16:17
名前: lightbox
オンラインライブラリを使わずに、この cdo_gmail.vbs だけで動作します
' ***********************************************************
' 使用するパラメータ
' ***********************************************************
strFrom = "わたしです <xxxxxxxx@gmail.com>"
strTo = "あなたです <xxxxxxxx@nifty.com>"

strServer = "smtp.gmail.com"
nPort = 465
strUser = "xxxxxxxx"
strPass = "パスワード"

' ***********************************************************
' オブジェクト
' ***********************************************************
Set Cdo = WScript.CreateObject("CDO.Message")

' ***********************************************************
' 自分のアドレスと宛先
' ***********************************************************
Cdo.From = strFrom
Cdo.To = strTo

' ***********************************************************
' 件名と本文
' ***********************************************************
Cdo.Subject	= "件名の文字列 / " & Now()
Cdo.Textbody = "テキスト本文" & vbCrLf & "改行は vbCrLf"

' ***********************************************************
' CC BCC HTMLメール( CC BCC はどちらか片方  )
' ※ 両方指定すると CC
' ***********************************************************
Cdo.Cc = "宛先1,宛先2"
Cdo.Bcc = "宛先1,宛先2"
Cdo.Htmlbody = "<img src=""http://winofsql.jp/image/winofsql.png"">"

' ***********************************************************
' ファイル添付あり
' ***********************************************************
Cdo.AddAttachment( "C:\Users\lightbox\Desktop\画像\_img.jpg" )
Cdo.AddAttachment( "C:\Users\lightbox\Downloads\del.gif" )

' ***********************************************************
' 設定
' ***********************************************************
Cdo.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
Cdo.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strServer
Cdo.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = nPort
Cdo.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = true

Cdo.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
Cdo.Configuration.Fields.Item _
 ("http://schemas.microsoft.com/cdo/configuration/sendusername") = strUser
Cdo.Configuration.Fields.Item _ 
 ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = strPass

' ***********************************************************
' 設定の反映
' ***********************************************************
Cdo.Configuration.Fields.Update

' ***********************************************************
' 送信
' ***********************************************************
on error resume next
Cdo.Send
if Err.Number <> 0 then
	strMessage = Err.Description
else
	strMessage = "送信が完了しました"
end if
on error goto 0

Wscript.Echo strMessage
このアーティクルの参照用URLをクリップボードにコピー メンテナンス
Yahoo! メール の場合の設定部分 ( No.3 )
日時: 2014/02/28 16:18
名前: lightbox
strFrom = "わたしです <xxxxxxxx@yahoo.co.jp>"
strTo = "あなたです <xxxxxxxx@nifty.com>"

strServer = "smtp.mail.yahoo.co.jp"
nPort = 465
strUser = "xxxxxxxx"
strPass = "パスワード"
このアーティクルの参照用URLをクリップボードにコピー メンテナンス