コメント |
http://lightbox.matrix.jp/ginpro/patio.cgi?mode=view2&f=285&no=0&w=910&type=ref&opt=text-align:left;margin-left:5px;&xml=y(Website Explorer) で出力されたファイルからサイト内リンクの HTML を作成します
※ 出来上がり見本 : http://argusobnurd.seesaa.net/article/172690848.html(マイクロアド、サイト内の全リンク)
[[CreateLinkFromWEBEX999.vbs]]
@DIV
' ファイルシステムオブジェクトの作成
' http://msdn.microsoft.com/ja-jp/library/cc409798.aspx
Set Fso = CreateObject( "Scripting.FileSystemObject" )
' Website Explorer の内部リンクリストのファイルを開く
Set objHandle = Fso.OpenTextFile( "List.wbx", 1 )
' 行単位に分解
aData = Split( objHandle.ReadAll, vbCrLf )
' ファイルを閉じる
objHandle.Close()
' ソート用レコードセットオブジェクト
Const adVarChar = 200
Set Rs = CreateObject("ADODB.Recordset")
Rs.Fields.Append "タイトル", adVarChar,255
Rs.Fields.Append "URL", adVarChar,255
Rs.Open
For I = 0 to Ubound(aData)-1 step 7
Rs.AddNew
Rs.Fields("タイトル").Value = aData(I)
Rs.Fields("URL").Value = Replace(aData(I+2),"[default]","")
Rs.Update
Next
' ソートキー
Rs.Sort = "タイトル"
' ポインタを先頭に戻す
Rs.MoveFirst
' 出力用ファイルを開く
Set objHandle = Fso.OpenTextFile( "microad.txt", 2, True )
Do while not Rs.EOF
buffer = "<a href="""
buffer = buffer & Rs.Fields("URL").Value & """ target=""microad"">"
buffer = buffer & Rs.Fields("タイトル").Value & "</a>"
objHandle.WriteLine buffer
Rs.MoveNext
Loop
' レコードセットを閉じる
Rs.Close
' 書き込んだテキストファイルを閉じる
objHandle.Close()
Wscript.Echo "処理が終了しました"
@END
|